مقالات آموزشی پردیس پارس

برای اطلاع از اضافه شدن جدیدترین مقالات و آموزش ها می توانید عضو کانال تلگرام پردیس پارس شوید.

 

بکاپ گیری خودکار از میکروتیک و ذخیره بر روی FTP

 بکاپ گیری خودکار از میکروتیک و ذخیره در FTP سرور

در این مقاله ما چگونگی تهیه بک آپ از تجهیزات میکروتیک به صورت خودکار و ارسال آن به سرور FTP را بررسی خواهیم کرد. همه امروزه از اهمیت بکاپ در دیوایس های شبکه مطلع هستیم به همین دلیل مهندس عطایی از تیم فنی پردیس پارس در قالب مقاله زیر به شما بکاپ گیری خودکار از میکروتیک را آموزش خواهد داد. شرکت پردیس پارس در زمینه خدمات شبکه مانند راه اندازی ایمیل سرور، کانفیگ سیسکو و خدمات میکروتیک، مجازی سازی شبکه و مجازی سازی دسکتاپ، راه اندازی شبکه و پشتیبانی شبکه فعالیت تخصصی دارد.

در ابتدا لازم است تنظیمات ساعت و تاریخ در روتر میکروتیک را تنظیم کنید که بهتر است برای اینکار از NTP سرور استفاده کنید ولی در این مقاله ما به صورت دستی از منوی System > Clock برای تنظیم تاریخ و ساعت استفاده می کنیم.

 

mikrotik backup

حالا به منوی System > Scripts بروید و یک Script جدید ایجاد نمایید مانند شکل زیر:

 

mikrotik backup

 

فقط کافیست در قسمت Source اسکریپت زیر را با جایگزینی اطلاعاتFTP سرور خود وارد نمایید.

 

# automated backup 2 External ftp

# ftp configuration

:local ftphost "<<FTP IP>>"

:local ftpuser "<<FTP USERNAME>>"

:local ftppassword "<<FTP PASSWORD>>"

:local ftppath "<<FTP PATH>>"

# months array

:local months ("jan","feb","mar","apr","may","jun","jul","aug","sep","oct","nov","dec");

# get time

:local ts [/system clock get time]

:set ts ([:pick $ts 0 2].[:pick $ts 3 5].[:pick $ts 6 8])

# get Date

:local ds [/system clock get date]

# convert name of month to number

:local month [ :pick $ds 0 3 ];

:local mm ([ :find $months $month -1 ] + 1);

:if ($mm < 10) do={ :set mm ("0" . $mm); }

# set $ds to format YYYY-MM-DD

:set ds ([:pick $ds 7 11] . $mm . [:pick $ds 4 6])

# file name for user manager backup - file name will be UMDB-servername-date-time.umb

:local fname ("/UMDB-".[/system identity get name]."-".$ds."-".$ts.".umb")

# file name for system backup - file name will be UMDB-servername-date-time.backup

:local fname1 ("/UMDB-".[/system identity get name]."-".$ds."-".$ts.".backup")

# file name for config export - file name will be UMDB-servername-date-time.rsc

:local fname2 ("/UMDB-".[/system identity get name]."-".$ds."-".$ts.".rsc")

# backup the data

/tool user-manager database save name=$fname

:log info message="User manager backup finished (1/3).";

/system backup save name=$fname1

:log info message="System backup finished (2/3).";

/export compact file=$fname2

:log info message="Config export finished (3/3)."

# upload the user manager backup

:log info message="Uploading user manager backup (1/3)."

/tool fetch address="$ftphost" src-path=$fname user="$ftpuser" mode=ftp password="$ftppassword" dst-path="$ftppath/$fname" upload=yes

# upload the system backup

:log info message="Uploading system backup (2/3)."

/tool fetch address="$ftphost" src-path=$fname1 user="$ftpuser" mode=ftp password="$ftppassword" dst-path="$ftppath/$fname1" upload=yes

# upload the config export

:log info message="Uploading config export (3/3)."

/tool fetch address="$ftphost" src-path=$fname2 user="$ftpuser" mode=ftp password="$ftppassword" dst-path="$ftppath/$fname2" upload=yes

# delay time to finish the upload - increase it if your backup file is big

:delay 60s;

# find file name start with UMDB- then remove

:foreach i in=[/file find] do={ :if ([:typeof [:find [/file get $i name] "UMDB-"]]!="nil") do={/file remove $i}; }

:log info message="Configuration backup finished.";

 

حال کافیست یک بار بر روی گزینه Run Script کلیک نمایید تا اسکریپت به صورت دستی Run شود و بکاپ ها در FTP سرور شما ذخیره گردد.

حال برای اینکه نیازی به اجرای دستی اسکریپت نباشه و خوده روتر به صورت خودکار Script را اجرا کنه به قسمت System > Scheduler می رویم و یک Schedule جدید ایجاد می نماییم مانند شکل زیر:

mikrotik backup



همانطور که در شکل بالا مشاهده می کنید این Schedule به صورت روزانه در ساعت 23:00:00 اسکریپت Auto-Backup را اجرا می نماید( در قسمت On Event نامی را که برای اسکریپت خود در نظر گرفتید را باید وارد نمایید).
حال با خیال راحت می توانید پشت میزتان چای بنوشید.

 

تهیه و تنظیم مقاله توسط مهندس احسان عطایی

مشاوره، اجرا و پشتیبانی شبکه های کامپیوتری را با پردیس پارس تجربه کنید

درخواست مشاوره

Poem

دنیا همانیست که با افکارمان خلقش می‌کنیم، تغییری نخواهد کرد مگر با تغییر دادن افکارمان. آلبرت انیشتین

در جستجوی نور باش، مطمئن باش آن را می‌یابی.

هیچ وقت به گمان اینکه وقت دارید ننشینید زیرا در عمل خواهید دید که همیشه وقت کم و کوتاه است.

هر قدر به طبیعت نزدیک شوی، زندگانی شایسته تری را پیدا می‌کنی. (نیما یوشیج)